# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=libxdmcp
pkgver=1.1.5
pkgrel=1
pkgdesc="X11 Display Manager Control Protocol library"
arch=('x86_64')
url="https://gitlab.freedesktop.org/xorg/lib/libxdmcp"
license=('MIT-open-group')
depends=('glibc' 'xorgproto')
makedepends=('xorg-util-macros')
provides=('libXdmcp.so')
source=(https://xorg.freedesktop.org//releases/individual/lib/libXdmcp-${pkgver}.tar.xz{,.sig})
sha512sums=('d7a1d70a58b7d34ddd01a91d3ccbc086a36626b7081cfcbb150d24288c6adad612b042ba7ea63a218595afb2ee04384c0f8ba84ee3c6bd29913724b54e898d83'
            'SKIP')

build() {
  cd libXdmcp-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc --disable-static
  make
}

package() {
  cd libXdmcp-${pkgver}
  make DESTDIR="${pkgdir}" install

  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}
