# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=mtdev
pkgver=1.1.7
pkgrel=1
pkgdesc="A stand-alone library which transforms all variants of kernel MT events to the slotted type B protocol"
arch=('x86_64')
url="https://bitmath.org/code/mtdev/"
license=('MIT')
depends=('glibc')
source=("$url$pkgname-$pkgver.tar.bz2")
sha512sums=('e6174a38cf67a7f12a3b91e4e27bf74a18d6b40a956950ebb748b0ff87092333daa07e647b26038a5a533f8c48e845d649848e6ba99ea009ab87fd96ed188152')

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr --disable-static
  make
}

check() {
  cd "$pkgname-$pkgver"
  make -k check
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install

  # license
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
}
