# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=libaio
pkgver=0.3.113
pkgrel=3
pkgdesc="The Linux-native asynchronous I/O facility (aio) library"
arch=(x86_64)
url="https://pagure.io/libaio"
license=(LGPL-2.0-or-later)
depends=(glibc)
provides=(libaio.so)
# LTO is not supported: https://pagure.io/libaio/issue/10
options=(!lto)
source=($url/archive/$pkgname-$pkgver/$pkgname-$pkgname-$pkgver.tar.gz)
sha512sums=('8058c927de0b5f7079fc232d2be23272537694bf271488af1dc0330b58afc307931792ab138512c5e00aa3ea921935a6d862f575fb0cc2bf323de63d8df208cd')
b2sums=('e06c1c1cc118c15f6bed1abfa97368d7ccc0d2e716a233cd4141936fb382e40909c340a6c882b18ee9461aaa23dd77a6644a38bdb5a00c1444538a2e0ab816d4')

prepare() {
  # -Werror, not even once
  sed 's/-Werror//' -i $pkgname-$pkgname-$pkgver/harness/Makefile

  # remove failing test until upstream fixes it
  rm -frv $pkgname-$pkgname-$pkgver/harness/cases/21.t
}

build() {
  make -C $pkgname-$pkgname-$pkgver
}

check() {
  make partcheck -k -C $pkgname-$pkgname-$pkgver
}

package() {
  make DESTDIR="$pkgdir" install -C $pkgname-$pkgname-$pkgver
  install -vDm 644 $pkgname-$pkgname-$pkgver/{ChangeLog,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
  install -vDm 644 $pkgname-$pkgname-$pkgver/man/*.3 -t "$pkgdir/usr/share/man/man3/"
}

