# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=bison
pkgver=3.8.2
pkgrel=8
pkgdesc="The GNU general-purpose parser generator"
arch=('x86_64')
license=('GPL-3.0-or-later')
url="https://www.gnu.org/software/bison/bison.html"
depends=(
  gettext
  glibc
  m4
  sh
)
source=("https://ftp.gnu.org/gnu/bison/${pkgname}-${pkgver}.tar.xz"{,.sig})
b2sums=('e211b61494c911f55b72a8b70b5a48cdf4000ce9e675a1f1f52735bb8f57d93a3f8075341451263af9c9c531004907ae2b62b1873e7e4664c2cd26fa3b12271c'
        'SKIP')
validpgpkeys=('7DF84374B1EE1F9764BBE25D0DDCAA3278D5264E')  # Akim Demaille

build() {
  cd "${pkgname}-${pkgver}"

  CFLAGS+=' -ffat-lto-objects' \
  ./configure --prefix=/usr --datadir=/usr/share
  make
}

check() {
  cd "${pkgname}-${pkgver}"
  make check
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}
