# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=libcloudproviders
pkgver=0.3.6
pkgrel=1
pkgdesc="DBus API that allows cloud storage sync clients to expose their services"
url="https://gitlab.gnome.org/World/libcloudproviders"
arch=(x86_64)
license=(LGPL-3.0-or-later)
depends=(glib2)
makedepends=(
  git
  gobject-introspection
  gtk-doc
  meson
  vala
)
_commit=9702091d5f77c2d1dfe1f8ca254c0910738da359  # tags/0.3.6^0
source=("git+https://gitlab.gnome.org/World/libcloudproviders.git#commit=$_commit")
b2sums=('7006ffb2fbb4336f42fa003e24b1be546ae2700e3d375f6b8ab9f05ffff2c06c663997bb2f72ee5328548441ff5595e2ba55395303442e16d9feab9065f01ff3')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd $pkgname
}

build() {
  local meson_options=(
    -D enable-gtk-doc=true
  )

  arch-meson $pkgname build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}

# vim:set sw=2 sts=-1 et:
