# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=double-conversion
pkgver=3.3.0
pkgrel=2
pkgdesc='Binary-decimal and decimal-binary routines for IEEE doubles'
arch=(x86_64)
url='https://github.com/google/double-conversion'
license=(BSD-3-Clause)
depends=(gcc-libs
         glibc)
makedepends=(cmake
             git)
source=(git+https://github.com/google/double-conversion#tag=v$pkgver)
sha256sums=('51285c0fb05d70a26f067110bec37e47d4b7705730b5c679d536baf95d5bb175')

build() {
  cmake -B build -S $pkgname \
      -DCMAKE_INSTALL_PREFIX=/usr \
      -DBUILD_SHARED_LIBS=ON
  cmake --build build
}

package () {
  DESTDIR="$pkgdir" cmake --install build

  install -Dm644 $pkgname/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}
