# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=kio-extras
pkgver=24.12.0
pkgrel=1
pkgdesc='Additional components to increase the functionality of KIO'
arch=(x86_64)
url='https://www.kde.org/'
license=(LGPL-2.0-or-later)
depends=(gcc-libs
         glibc
         karchive
         kcmutils
         kconfig
         kcoreaddons
         kdbusaddons
         kdnssd
         kdsoap-qt6
         kdsoap-ws-discovery-client
         ki18n
         kio
         kservice
         ktextwidgets
         kwidgetsaddons
         libimobiledevice
         libkexiv2
         libmtp
         libplist
         libssh
         libxcursor
         phonon-qt6
         plasma-activities
         qt6-5compat
         qt6-base
         qt6-svg
         ripgrep-all
         smbclient
         solid
         syntax-highlighting)
makedepends=(extra-cmake-modules
             gperf
             kdoctools
             libappimage
             openexr
             plasma-activities-stats
             qcoro
             taglib)
optdepends=('icoutils: Windows executable thumbnails'
            'kimageformats: thumbnails for additional image formats'
            'libappimage: AppImage thumbnails'
            'openexr: EXR format thumbnails'
            'perl: info kioslave'
            'plasma-activities-stats: recently used kioslave'
            'qt6-imageformats: thumbnails for additional image formats'
            'taglib: audio file thumbnails')
groups=(kde-applications
        kde-network)
source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('5131e77f3771320d65cde43cef6fd3eb9d59bf551cad6e90753b354ff15df2c4'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DLIBAPPIMAGE_LIBRARIES=libappimage.so \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}
