# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=gmp
pkgver=6.3.0
pkgrel=2
pkgdesc='A free library for arbitrary precision arithmetic'
arch=(x86_64)
url='https://gmplib.org/'
depends=(gcc-libs
         glibc)
license=(GPL-2.0-or-later
         LGPL-3.0-or-later)
source=(https://gmplib.org/download/gmp/gmp-$pkgver.tar.lz{,.sig})
sha256sums=('be5c908a7a836c3a9bd9d62aa58563c5e9e7fef94c43a7f42dbc35bb6d02733c'
            'SKIP')

build() {
  cd $pkgname-$pkgver
# Enable shadow stack support
  LDFLAGS+=' -Wl,-z,shstk' \
  ./configure --build=${CHOST} \
    --prefix=/usr \
    --enable-cxx \
    --enable-fat
# Fix overlinking
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}
