# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=libbpf
pkgver=1.4.3
pkgrel=1
pkgdesc='Library for loading eBPF programs and reading and manipulating eBPF objects from user-space'
url='https://github.com/libbpf/libbpf'
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  glibc
  libelf
  linux-api-headers
  zlib
)
makedepends=(
  rsync
)
provides=(libbpf.so)
source=(https://github.com/libbpf/libbpf/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha512sums=('d03965f8abeaac840cda28fdacf9df378869fa6e5ef45d992fc5398bed5970ebedb24f20676b1779f8941b4b912bb691948e198eff87ea1d5d8e5cd95d6e06d1')
b2sums=('a5440a6ba64cf5f0783ec49e3e1f13badf9fc7acc4c3ffd2ec9a499b68fb668a0b9ca9fa482d53d2e0f3d698ffe4e251e5159d668d9e41fab066912553196a81')

build() {
  cd ${pkgname}-${pkgver}
  make -C src
}

package() {
  cd ${pkgname}-${pkgver}
  make -C src DESTDIR="${pkgdir}" LIBSUBDIR=lib install install_headers
  install -Dm 644 LICENSE* -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: ts=2 sw=2 et:
