# Packager = Tuxcore <dev@tuxcore.org> 
pkgname=libusbmuxd
pkgver=2.1.0
pkgrel=1
pkgdesc='Client library to multiplex connections from and to iOS devices'
arch=('x86_64')
url='https://libimobiledevice.org/'
license=('GPL-2.0-or-later AND LGPL-2.1-or-later')
depends=('gcc-libs' 'glibc' 'libimobiledevice-glue' 'libplist')
makedepends=('git')
source=("git+https://github.com/libimobiledevice/libusbmuxd.git#tag=$pkgver")
b2sums=('6497cf5ac4a3af89ec41f8e9bc19540124d759404737af832d87fd99a7ad1781d83fc6524a16fb64196dc1615a58a73c8e8913627220d55eecff68db34feed0c')

prepare() {
  cd $pkgname
  autoreconf -fi
}

build() {
  cd $pkgname
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}
